InTechSpot  

Step 1
Download Internet Explorer 7 Beta 2.

Step 2
Use WinRar (you can download a free trial) to extract the files from the setup to a folder, for example C:\Program Files\Internet Explorer 7.
If you don't want to use WinRar, run the command prompt, go to the folder where the exe is located and type "IE7BETA2-WindowsXP-x86-enu.exe -e" (or the appropriate setup name). You'll see a dialog that lists the files extracted. You have to remember the folder where the files are extracted, go there and copy it to C:\Program Files\Internet Explorer 7. Don't press OK on the message box that will appear until you have copied the folder, otherwise the folder will be deleted.

Step 3
Create a new file named ie7.bat in that folder, and copy the code below (courtesy of Jon Galloway):

@ECHO OFF
TITLE IE7 Launcher 1.4

ECHO IE7 STANDALONE LAUNCHER 1.4
ECHO Updated for IE7 Beta 2 Preview
ECHO.
ECHO Do not close this window or it will not clean up after itself properly.
ECHO You can pass a URL into this batch file, like this:
ECHO ie7.bat www.microsoft.com
ECHO.
ECHO More info here: http://weblogs.asp.net/jgalloway/archive/2005/12/28/434132.aspx
ECHO.
ECHO When you close IE7, this will remove the registry key and shut itself down.
ECHO.
ECHO Setting up IE7 for standalone mode...
PUSHD %~dp0

ECHO Removing IE7 registry key and set the version vector to "7.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}]
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\Interface\{000214E5-0000-0000-C000-000000000046}]
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="7.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg

REN SHLWAPI.DLL SHLWAPI.DLL.BAK
TYPE NUL > IEXPLORE.exe.local
ECHO Running IE7...
iexplore.exe "%1"

:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
:: Delete the temporary REG file
DEL %TEMP%.\IE7Fix.reg

ECHO Removing IE7 standalone files...
REN SHLWAPI.DLL.BAK SHLWAPI.DLL
DEL IEXPLORE.exe.local

:: Set the old version vector "6.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="6.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
REGEDIT /S %TEMP%.\IE7Fix.reg
DEL %TEMP%.\IE7Fix.reg

POPD
ECHO Complete, closing...

Step 4
In the same folder, create a new file ie7.vbs with this code:
Set oShell = CreateObject("WScript.Shell")
oShell.Run "ie7.bat", 0, True

Step 5
Create a shortcut on the desktop to ie7.vbs and run Internet Explorer 7 from that shortcut.

Now you have a standalone Internet Explorer 7 that runs along with Internet Explorer 6.
Known problems: while running IE7, if you type an URL in the address bar of IE6, the page will open in a new window. Another problem is that IE7 won't have tabs. But remember, you just want to test how pages are rendered, not have a full working browser.

Test Internet Explorer 7 Without Installing It [Google Operating System]
Remove IE 7 or run it with IE 6!